*-----------------------------------------------------------------------
* Filename:		6146s.inc  13/8/97
* Simulator:		SPICE 3f4
* Device type:		RF beam tetrode
* Device model:		6146
*
* Author:		Duncan Munro
* Date:			13/8/97
* Copyright:		(C)1997-2000 Duncan Amplification
* 
* The following parameters are not modelled:
*
*   (1) Heater
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Email queries to postmaster@duncanamps.com
*
* Pins   A  Anode
*        S  Screen
*        G  Grid
*        K  Cathode
*
*-----------------------------------------------------------------------

.SUBCKT 6146 A S G K
*
* Calculate contribution to cathode current
*
Bat	at  0	V=0.636*ATAN(V(A,K)/10)
Bme	me  0   V=URAMP(V(A,K)/130)
Bmup	mup 0	V=1-(URAMP(V(K,G)-30)/2000)
Bmu     mu  0	V=V(G,K)*V(mup)
Bgs	gs  0	V=URAMP(V(S,K)*4.5+V(mu)*19+URAMP(V(A,K))/10)
Bgs2	gs2 0	V=(V(gs)^1.5)*16E-6
Bsd	sd  0	V=URAMP(V(gs2)*V(at)-v(me))
Bcath	cc  0	V=V(gs2)*V(at) - V(sd)
*
* Calculate anode current
*
Ba	A   K	I=V(cc)
*
* Calculate screen current
*
Bscrn	sc  0	V=2.5E-4*(V(S,K)^1.5)*V(gs2)*(1.1-V(at))+V(sd)
Bs	S   K	I=V(sc)
*
* Grid current
*
*Bg	G   K	I=(URAMP(V(G,K)+1)^1.5)*(1.25-V(at))*870E-6
*
* Capacitances
*
Cg1	G	K	13.0p
Cak	A	K	8.5p
Cg1a	G	A	0.24p

.ENDS