*-----------------------------------------------------------------------
* Filename:		6N1P.inc  V1  25/10/97
* Simulator:		PSpice
* Device type:		Triode
* Device model:		Svetlana 6N1P
*
* Author:		Duncan Munro
* Date:			25/10/97
* Copyright:		(C)1997-2000 Duncan Amplification
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Email queries to postmaster@duncanamps.com
*
* Pins   A  Anode
*        G  Grid
*        K  Cathode
*
*-----------------------------------------------------------------------

.SUBCKT 6N1P A G K

************************************************************************
*
* Anode model
*
* Models reduction in mu at large negative grid voltages
* Models change in Ra with negative grid voltages
* Models limit in Ia with high +Vg and low Va
*
* PARAMETERS
*
*	LIP Conduction limit exponent
*	LIF Conduction limit factor
*	RAF Anode resistance factor for neg grid voltages
*	RAP Anode resistance factor for positive grid voltages
*	MU0 Mu between grid and anode at Vg=0
*	MUR Mu reduction factor for large negative grid voltages
*	EMC Emission coefficient
*	GCF Grid current scale factor
*
************************************************************************

.PARAM LIP 1
.PARAM LIF 1E-3
.PARAM RAF 9E-3
.PARAM RAP 4E-3
.PARAM MU0 38
.PARAM MUR 19E-3
.PARAM EMC 9.6E-6
.PARAM GCF 213E-6
Elim  LI 0  VALUE {PWR(LIMIT{V(A,K),0,1E6},{LIP})*{LIF}}
Erpf  RP 0  VALUE {1+LIMIT{V(G,K),0,-1E6}*{RAF}+LIMIT{V(G,K),0,1E6}*{RAP}}
Egr   GR 0  VALUE {LIMIT{V(G,K),0,1E6}+LIMIT{V(G,K)*(1+V(G,K)*{MUR}),0,-1E6}}
Eem   EM 0  VALUE {LIMIT{V(A,K)*V(RP)+V(GR)*{MU0},0,1E6}}
Eep   EP 0  VALUE {PWR(V(EM),1.5)*{EMC}}
Eel   EL 0  VALUE {LIMIT{V(EP),0,V(LI)}}
Eld   LD 0  VALUE {LIMIT{V(EP)-V(LI),0,1E6}}
Ga    A  K  VALUE {V(EL)}

************************************************************************
*
* Grid current model
*
* Models grid current, along with rise in grid current at low Va
*
************************************************************************
Egf   GF 0  VALUE {PWR(LIMIT{V(G,K),0,1E6},1.5)*{GCF}}
Gg    G  K  VALUE {(V(GF)+V(LD))}

*
* Capacitances
*
Cgk	G	K	2.4p
Cga	A	G	3.9p
Cak	A	K	0.7p

.ENDS