*-----------------------------------------------------------------------
* Filename:		SV811-3.inc  V2  16/6/97
* Simulator:		PSpice
* Device type:		Power triode
* Device model:		Svetlana SV811-3
*
* Author:		Duncan Munro
* Date:			14/6/97
* Copyright:		(C)1997-2000 Duncan Amplification
*
* The following parameters are not modelled:
*
*   (1) Filament: A "cathode" connection is made which
*       should be connected to a potential which is the
*	average of the two filament terminals.
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Email queries to postmaster@duncanamps.com
*
* Pins   A  Anode
*        G  Grid
*        K  Cathode
*
*-----------------------------------------------------------------------

.SUBCKT SV811-3 A G K
*
* Calculate contribution to cathode current
*
Eat	at	0	VALUE={0.636*ATAN(V(A,K)/30)}
Eme	me	0	VALUE={PWR(LIMIT{V(A,K),0,10000},1.5)/4500}
Emu	mu	0	VALUE={V(G,K)}
Egs	gs	0	VALUE={LIMIT{V(A,K)+V(mu)*3.4,0,1E6}}
Egs2	gs2	0	VALUE={PWRS(V(gs),1.5)*25E-6}
Ecath  	cc    	0 	VALUE={LIMIT{V(gs2),0,V(me)}}
*
* Calculate anode current
*
Ga     	A     	K     	VALUE={V(cc)}
*
* Calculate grid current
*
Gg	G	K	VALUE={PWR(LIMIT{V(G,K)+1,0,1E6},1.5)*(2-V(at))*30E-6}
*
* Capacitances
*
Cgk	G	K	7p
Cga	A	G	8p

.ENDS